VB.NET JSONとオブジェクトを変換する

VB.NETのJSONとオブジェクトを変換するサンプルです。

目次	JSONからオブジェクトに変換する
	オブジェクトからJSONに変換する

JSONからオブジェクトに変換する

Public Shared Function DeserializeObject(Of T)(value As String) As T

Public Shared Function DeserializeObject(value As String) As <NullableAttribute(2)> Object

DeserializeObjectメソッドは、JSONをオブジェクトに変換します。
デシリアライズとも呼ばれます。
Newtonsoft.Jsonの参照の設定が必要です。
→参照の追加＞アセンブリ＞Json.NET .NET 4.0
→無い場合は、NuGet パッケージの管理からNewtonsoft.Jsonを取得
ASP.NETではNewtonsoft.Jsonはデフォルトで設定されています。

JSONをオブジェクトにする

JSONをオブジェクトにするサンプルです。

１．JSONデータ

{
    "id": 1,
    "name": "鈴木",
    "sikaku": [
        "基本",
        "応用"
    ]
}

２．JSONを変換する

Imports Newtonsoft.Json

Module Module1
	Public Class Syain1
		Public Property id As Integer
		Public Property name As String
		Public Property sikaku As String()
	End Class
	Sub Main()

		Dim Json1 As String = "{""id"":  1,""name"":""鈴木"",""sikaku"":[""基本"",""応用""]}"

		'クラスにマッピングする
		Dim syain1 As Syain1 = JsonConvert.DeserializeObject(Of Syain1)(Json1)
		Console.WriteLine(syain1.id) '1
		Console.WriteLine(syain1.name) '鈴木
		Console.WriteLine(syain1.sikaku(0)) '基本
		Console.WriteLine(syain1.sikaku(1)) '応用

		'クラスにマッピングしない
		Dim syain2 As Object = JsonConvert.DeserializeObject(Json1)
		Console.WriteLine(syain2("id")) '1
		Console.WriteLine(syain2("name")) '鈴木
		Console.WriteLine(syain2("sikaku")(0)) '基本
		Console.WriteLine(syain2("sikaku")(1)) '応用
	End Sub
End Module

1行目は、Newtonsoft.Jsonをインポートしています。

14行目は、4～8行目のクラスにマッピングするやり方です。
DeserializeObjectメソッドでJSONをオブジェクトにしています。

21行目は、クラスにマッピングしないやり方です。
15～18行目と22～25行目は値のアクセスの仕方が異なります。

オブジェクトからJSONに変換する

Public Shared Function SerializeObject(<NullableAttribute(2)> value As Object) As String

SerializeObjectメソッドは、オブジェクトをJSONに変換します。
戻り値は「String型」です。
シリアライズとも呼ばれます。
Newtonsoft.Jsonの参照の設定が必要です。
→参照の追加＞アセンブリ＞Json.NET .NET 4.0
→無い場合は、NuGet パッケージの管理からNewtonsoft.Jsonを取得
ASP.NETではNewtonsoft.Jsonはデフォルトで設定されています。
以下は、newtonsoftのリンクです。
https://www.newtonsoft.com/json

オブジェクトをJSONにする

オブジェクトをJSONにするサンプルです。

Imports Newtonsoft.Json

Module Module1
	Public Class Syain
		Public Property id As Integer
		Public Property name As String
		Public Property sikaku As String()
	End Class
	Sub Main()
		Dim syain1 As Syain = New Syain()
		syain1.id = 1
		syain1.name = "鈴木"
		syain1.sikaku = {"基本", "応用"}

		Dim Json As String = JsonConvert.SerializeObject(syain1)
		Console.WriteLine(Json) 'JSONを出力
	End Sub
End Module

1行目は、Newtonsoft.Jsonをインポートしています。
4～8行目はクラスです。
10行目でオブジェクト(インスタンス)を生成し11～13行目で値を設定しています。
15行目は、SerializeObjectメソッドでオブジェクトをJSONにしています。

結果は以下のようにJSONを取得できます。

{
    "id": 1,
    "name": "鈴木",
    "sikaku": [
        "基本",
        "応用"
    ]
}